home *** CD-ROM | disk | FTP | other *** search
/ IRIX 6.4 Applications 1997 August / SGI IRIX 6.4 Applications 1997 August.iso / dist / mmailp.idb / usr / lib / Zmail / bin / showaudio.z / showaudio
Encoding:
Text File  |  1997-01-22  |  6.2 KB  |  213 lines
  1. #!/bin/csh -fb
  2. # (The "-fb" might need to be changed to "-f" on some systems)
  3. #
  4. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  5. # 
  6. # Permission to use, copy, modify, and distribute this material 
  7. # for any purpose and without fee is hereby granted, provided 
  8. # that the above copyright notice and this permission notice 
  9. # appear in all copies, and that the name of Bellcore not be 
  10. # used in advertising or publicity pertaining to this 
  11. # material without the specific, prior written permission 
  12. # of an authorized representative of Bellcore.  BELLCORE 
  13. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  14. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  15. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  16. #
  17.  
  18.  
  19. if (! $?METAMAIL_TMPDIR) then
  20.     set METAMAIL_TMPDIR=/tmp
  21. endif
  22.  
  23. # First, figure out which machine to play it on!
  24. set thishost=`hostname`
  25.  
  26. # Note that there are some special lines in here that only work at Bellcore,
  27. # Specifically involving phone playback from the machine "greenbush".
  28. # Everything should work fine at other sites, though
  29. set AUDIOBINDIR=/u/andrew/phone-sau/bin
  30. set AUDIOPHONEHOST=greenbush
  31. set AUDIOPHONEHOSTLONG=greenbush.bellcore.com
  32. set AUDIOLOGMAIL=andrew@thumper.bellcore.com
  33. set ORG="Bellcore"
  34. set STDINPUT=0
  35. if ("$1" == "-p") then
  36.     set AUDIOPHONE=$2
  37.     shift
  38.     shift
  39. endif
  40. if ("$1" == "-s") then
  41.     set AUDIOSPEAKERFORCE = 1
  42.     shift
  43. endif
  44. if ($?AUDIOPHONE || $?AUDIOPHONEFORCE) then
  45.     goto playphone
  46. endif
  47. if (! -d $AUDIOBINDIR) then
  48.     set AUDIOSPEAKERFORCE=1
  49. endif
  50.  
  51. if ("$1" == "-") then
  52.     set STDINPUT=1
  53.     shift
  54. endif
  55. if ($#argv < 1) then
  56.     set STDINPUT=1
  57. endif
  58.     
  59. if (! $STDINPUT && ! $?AUDIOSPEAKERFORCE && ! $?AUDIOPHONEFORCE) then
  60.     if ($?MM_NOTTTY) then
  61.     if ($MM_NOTTTY == 1) then
  62.         setenv MM_NOTTTY 0
  63.         xterm -e showaudio $*:q
  64.         exit 0
  65.     endif
  66.     endif
  67. choosehardware:
  68.     echo This program can display audio on the speakers of some workstations, 
  69.     echo "or (at some sites) it can call you on the telephone.  Please choose one:"
  70.     echo ""
  71.     echo "1 -- Use the computer's speaker"
  72.     echo "2 -- Call me on the telephone"
  73.     echo ""
  74.     echo -n "Which do you prefer (1 or 2)? "
  75.     set ans=$<
  76.     if ($ans == 2)  then
  77.     echo "OK, we'll use the telephone..."
  78.     set AUDIOPHONEFORCE=1
  79.     echo "In the future, you can avoid this question by setting the environment variable"
  80.     echo "AUDIOPHONEFORCE to 1"
  81.     goto playphone
  82.     else if ($ans == 1) then
  83.         echo "OK, Attempting to play the audio using your computer's speaker.."
  84.         set AUDIOSPEAKERFORCE=1
  85.     echo "In the future, you can avoid this question by setting the environment variable"
  86.     echo "AUDIOSPEAKERFORCE to 1"
  87.     else
  88.     echo "That is NOT one of your choices."
  89.     goto choosehardware
  90.     endif
  91. endif
  92.  
  93. set audiohost=$thishost
  94. if ($?DISPLAY) then
  95.     set audiohost=`echo $DISPLAY | sed -e 's/:.*//'`
  96.     if ($audiohost == "unix") set audiohost=$thishost
  97.     if ($audiohost == "") set audiohost=$thishost
  98. endif
  99. if ($?AUDIOHOST) then
  100.     set audiohost=$AUDIOHOST
  101. endif
  102.  
  103. if ($audiohost != $thishost) then
  104.     echo Sending audio to $audiohost...
  105.     if ($?MMS_AUDIO) then
  106.         if ($STDINPUT) then
  107.             cat | mms -host $audiohost "show audio/basic" -
  108.         else
  109.             cat $*:q | mms -host $audiohost "show audio/basic" -
  110.         endif
  111.         exit 0
  112.     endif
  113.  
  114. # The next two lines are very inefficient, but not everyone has their path right for an rsh
  115.     pushd ~ >& /dev/null
  116.     set thisprog=`which showaudio`
  117.     popd >& /dev/null
  118.     if ($STDINPUT) then
  119.         cat | rsh $audiohost $thisprog -s -
  120.     else
  121.         cat $*:q | rsh $audiohost $thisprog  -s -
  122.     endif
  123.     exit 0
  124. endif
  125.  
  126. if (-f /usr/sbin/sfplay) then
  127.     if ($#argv >= 1) then
  128.     exec /usr/sbin/sfplay -i mu-law chan 1 rate 8000 end $*:q
  129.     else
  130.     cat > ${METAMAIL_TMPDIR}/audio.$$
  131.     /usr/sbin/sfplay -i mu-law chan 1 rate 8000 end ${METAMAIL_TMPDIR}/audio.$$
  132.     rm ${METAMAIL_TMPDIR}/audio.$$
  133.     exit 0
  134.     endif
  135. else if (-d /usr/sony) then
  136.     set dev=/dev/sb0
  137. else if (-e /usr/bin/audioplay) then
  138. #  Solaris 2.0
  139.     /usr/bin/audioconvert -i raw,voice -f sun $*:q | /usr/bin/audioplay
  140.     exit $status
  141. else if (-e /bin/audioplay) then
  142. #  Solaris 2.0
  143.     /bin/audioconvert -i raw,voice -f sun $*:q | /bin/audioplay
  144.     exit $status
  145. else
  146.     set dev=/dev/audio
  147. endif
  148.  
  149. if (-w $dev) then
  150. echo Playing audio on $thishost using $dev, one moment please...
  151. if ($#argv >= 1) then
  152.         cat $*:q > $dev
  153. else
  154.         cat > $dev
  155. endif
  156. exit 0
  157. endif
  158.  
  159. playphone:
  160. if (-d $AUDIOBINDIR) then
  161.               set thisprog=`which showaudio`
  162.     if (! $?AUDIOPHONE) then
  163.         if ($?MM_NOTTTY) then
  164.         if ($MM_NOTTTY == 1) then
  165.             setenv MM_NOTTTY 0
  166.             xterm -e $thisprog $*:q
  167.             exit 0
  168.         endif
  169.         endif
  170.         echo This message contains audio, which can be sent to your telephone.
  171.         echo Please enter the telephone number at which you would like to hear this
  172.         echo -n "audio message as you would dial it from INSIDE ${ORG}:  "
  173.         set AUDIOPHONE=$<
  174.     endif
  175.     if ($thishost == $AUDIOPHONEHOST || $thishost == $AUDIOPHONEHOSTLONG) then
  176.         echo Calling Phone number $AUDIOPHONE
  177.         echo "You MUST SAY HELLO when you answer the phone, or you will not hear the message."
  178.         mail -s "showaudio: `whoami` called $AUDIOPHONE" $AUDIOLOGMAIL < /dev/null
  179.         if ($STDINPUT) then
  180.             cat $AUDIOBINDIR/../GREET.au $*:q - | $AUDIOBINDIR/play -\# $AUDIOPHONE -
  181.         else
  182.             cat $AUDIOBINDIR/../GREET.au $*:q | $AUDIOBINDIR/play -\# $AUDIOPHONE -
  183.         endif
  184.         echo All done
  185.         exit 0
  186.     else
  187.         echo Trying to rsh to $AUDIOPHONEHOST to send audio via telephone
  188.         cat $*:q | rsh $AUDIOPHONEHOST $thisprog -p $AUDIOPHONE -
  189.         exit 0
  190.     endif
  191. endif
  192. echo ""
  193. echo This message contains an audio mesage, which can not currently be
  194. echo played on this type of workstation.   If you log into an appropriate 
  195. echo "machine (currently a SPARCstations or Sony News workstation)"
  196. echo and read this message there, you should be able to hear the audio
  197. echo message.  
  198. echo ""
  199. if (! $?MM_NOTTTY) set MM_NOTTTY=0
  200. if ($MM_NOTTTY == 1) then
  201.     set fname=/tmp/mm.aud.$$
  202. else
  203.     echo -n "Do you want to write the audio out to a file [y] ? "
  204.     set ANS=$<
  205.     if ("$ANS" =~ n* ||  "$ANS" =~ N* ) exit 0
  206.     echo -n "File name:"
  207.     set fname=$<
  208. endif
  209. cp $1 $fname
  210. if ($status == 0) echo Wrote raw audio file: $fname
  211. exit 0
  212.  
  213.